% RA: respuestas-3.in
% ¿Qué parejas pueden casarse?
% Departamento de Ciencias de la Computación e Inteligencia Artificial
% Universidad de Sevilla
%==============================================================================


%==============================================================================
% Enunciado
%==============================================================================

%   De las siguientes personas Juan, Jorge, Víctor, María, Agata y Carla se
% sabe que María, Jorge y Victor son ricos y que María y Juan se aman, que
% Víctor ama a María y que Jorge y Víctor se aman. Admitiendo que dos personas
% pueden casarse si son de distintos sexo y se aman o una es rica y ama a la
% otra, determinar las parejas que pueden casarse.

%==============================================================================
% Formalización
%==============================================================================

set(ur_res).
assign(max_proofs, -1).

list(usable).
 Hombre(Juan).
 Hombre(Jorge).
 Hombre(Victor).

 Mujer(Maria).
 Mujer(Agata).
 Mujer(Carla).

 Rico(Maria).
 Rico(Jorge).
 Rico(Victor).

 Ama(Maria, Juan).
 Ama(Juan, Maria).
 Ama(Victor, Maria).
 Ama(Jorge, Victor).
 Ama(Victor, Jorge).

% Los hombres y las mujeres son de sexos distintos:
 -Mujer(x) | -Hombre(y) | Distinto_sexo(x,y).
 -Mujer(x) | -Hombre(y) | Distinto_sexo(y,x).

% Dos personas de distintos sexo pueden casarse si se aman o una es rica y ama
% a la otra:
 -Distinto_sexo(x,y) | -Ama(x,y) | -Ama(y,x) | Pueden_casarse(x,y).
 -Distinto_sexo(x,y) | -Ama(x,y) | -Rico(x) | Pueden_casarse(x,y).
end_of_list.

list(sos).
% ¿Qué parejas pueden casarse?:
 -Pueden_casarse(x,y) | $ANS(x,y).
end_of_list.

%==============================================================================
